Hallo haiflosse,
Deine Angaben sind tatsächlich etwas ungenau.
Solltest Du den besagten Eintrag brauchen, weil Du und andere User Accounts in der Console arbeiten müssen/sollen (was ich mal stark annehme), so bedenke, dass über den Code von totsch (Beitrag 3) die Umgebungsvariable global geändert wird.
Nach dem Erstellen ist auf jeden Fall ein Reboot fällig.
eingeloggte User (nach dem Reboot) können den neu erstellen Pfad u.U. trotzdem nicht oder nur teilweise erreichen, wenn sie Benutzer mit eingeschränkten Rechten sind oder der erstellte User-Pfad Teil eines "abgeschlossenen" Admin-Accounts ist
Sollten alle User die Console als admin öffnen können so ist ab Win8/8.1 zu bedenken, dass erstellte Netzwerkpfade, die über den Explorer erstellt worden
sind (immer als User, nicht als Admin) in einer Admin-Console nicht verfügbar sind
Mein Vorschlag an Dich ist eine Batch zu schreiben, diese irgendwo zu plazieren und evtl. einen Link zu dieser Batch in einem gemeinsamen Ordner zu erstellen.
Diese Batch eröffnet dann jedem User innerhalb der Windows Session einen temporären, direkten Zugang zum besagten Pfad
Kopiere meinen unteren Code in einen Editor
Passe den Code an der genannten Stelle an (Pfadangabe)
Benenne die Datei und gib ihr die Dateiendung *.cmd
Plaziere sie in einem Verzeichnis welches jeder User erreichen kann
Wenn Du möchtest erstelle einen Link zu dieser Batch entweder im selben Verzeichnis oder auch woanders
Code:
@ECHO OFF
(Title %~n0-Console)
SETLOCAL ENABLEEXTENSIONS
:: Diese batch ändert den Umgebungspfad ["PATH" Variable]
:: Alle Variablendeklarationen zwischen Setlocal und Endlocal
:: sind temporär und werden danach ungültig
(SET FOOT= ___________________________________________________________________________)
(SET HEAD= ***************************************************************************)
:: Header
ECHO.&ECHO %HEAD%&ECHO.
ECHO %~n0 Konsole
ECHO.&ECHO %HEAD%&ECHO.
:: Umgebungsvariable erstellen, die auf den Pfad des Aufrufes der Konsole zeigt
(SET CALLED=%CD%)
:: Umgebungsvariable erstellen, die auf den Pfad dieser Batch-Datei zeigt
(SET HERE=%~dp0)
:: abschliessenden Backslash der beiden erstellten Umgebungsvariablen entfernen
IF "%CALLED:~-1%"=="\" (SET CALLED=%CALLED:~0,-1%)
IF "%HERE:~-1%"=="\" (SET HERE=%HERE:~0,-1%)
:: Check ob der Pfad zum gewünschten User Account existiert - Wenn Ja Setzen - Wenn Nein Exit
:: Hier bitte deinen gewünschten Pfad eintragen
:: Falls der Pfad Leerzeichen enthält, muss dieser mit Anführungszeichen eingeschlossen werden
DIR /B "GEWÜNSCHTER PFAD" >NUL 2>&1 && (SET BIN=GEWÜNSCHTER PFAD OHNE ANFÜHRUNGSZEICHEN!!!)
IF NOT DEFINED BIN ECHO.&&ECHO [GEWÜNSCHTER PFAD] existiert nicht.&&ECHO.&&GOTO:_END
:: Pfad and die Pfadvariable anhängen
IF DEFINED PATH SET PATH=%PATH%;%BIN%
ECHO.
ECHO Pfadvariable geändert.
ECHO.
ECHO BIN = "%BIN%"
ECHO CALLED = "%CALLED%"
ECHO HERE = "%HERE%"
ECHO.
:: Footer
:_END
ECHO %FOOT%
ECHO.
ECHO.
CMD /K&ENDLOCAL
